EXCEL VBA Dir関数（２）・ファイル操作・フォルダー・サブフォルダー操作（ファイル存在・ファイル一覧）

EXCEL VBA Dir関数（２）・ファイル操作・フォルダー・サブフォルダー操作（ファイル存在・ファイル一覧）

'
'
Sub Dir00A()

     Dim Hen As String '変数を設定
     
     Hen = Dir("C:\TEST\Excel.xlsx") 'CドライブのTESTフォルダー内のExcel.xlsxファイルの存在を確認します。
     
     MsgBox Hen 'ファイルの存在結果をメッセージボックスに表示します。

End Sub
'

'
'
Sub Dir00B()

    Dim Hen, Files As String  '変数を設定

    Hen = Dir("C:\TEST\*.xlsx")  'CドライブのTESTフォルダー内の拡張子xlsxのファイルの存在を確認します。1件目

    Do While Hen <> ""  'フォルダー内のファイルが無くなるまで繰り返します。
        Files = Files & Hen & vbLf  'フォルダー内のファイルを加算します。
        Hen = Dir()  'ファイルの2件目以降のファイルの存在を確認します。
    Loop
    
    MsgBox Files  'フォルダー内の拡張子（xlsx）ファイル名を表示します。

End Sub
’

EXCEL VBA Dir関数　指定したフォルダー内のファイル数をカウントする。

'
'
Sub Dir01()  '指定したフォルダー内ファイル数をカウントします。
    
    Dim CountF As Long
    Dim Files As String
    
    CountF = 0  'カウント０：初期設定
    
    Files = Dir("C:\Windows\*.*")  'ファイル数をカウントするフォルダーの指定
    
    Do While Files <> ""  'フォルダー内のファイルが無くなるまで繰り返す。
        
        CountF = CountF + 1  'ファイル数をカウントする。
        Files = Dir()  '次のファイルを読み込みます。
          '（ファイルが有れば、Files＝ファイル名・ファイルが無ければ””：Files＝無し）
    
    Loop
    
    MsgBox "ファイルは" & CountF & "個有りました。"  '最後にファイル数を表示します。

End Sub
'

EXCEL VBA Dir関数　指定したフォルダー内のファイル一覧をシートに表示する。(ファイル名・ファイル容量・更新日時)

'
'
Sub Dir02() '指定したフォルダー内のファイル一覧をシートに表示する。(ファイル名・ファイル容量・更新日時)
    
    Dim CountF As Long
    Dim Files As String
    
    With ActiveSheet
        .Cells.ClearContents 'ワークシートのクリアー（文字列削除）
        .Cells(1, "A") = "No"
        .Cells(1, "B") = "ファイル名"
        .Cells(1, "C") = "ファイル容量"
        .Cells(1, "D") = "更新日時"
     
    CountF = 2   '：初期設定 2行目
    
    Files = Dir("C:\TEST\*.xls?")  'ファイル数をカウントするフォルダーの指定
    
    Do While Files <> ""  'ファイルが無くなるまで繰り返す。
       
        .Cells(CountF, "A") = CountF - 1  '番号
        .Cells(CountF, "B") = Files  'ファイル名
        .Cells(CountF, "C") = FileLen("C:\TEST\" & Files)  'ファイルの容量
        .Cells(CountF, "D") = FileDateTime("C:\TEST\" & Files) 'ファイルの更新日時
        
        CountF = CountF + 1  'ファイル数をカウントする。
        
        Files = Dir()  '次のファイルを読み込みます。
          '（ファイルが有れば、Files＝ファイル名・ファイルが無ければ””：Files＝無し）
    Loop

    End With

End Sub
'

EXCEL VBA Dir関数　サブフォルダーを含めて全てのファイル一覧を出力する。※再帰呼び出し

'
'
'
Sub Dir04() 'サブフォルダーを含めて全てのファイル一覧を出力する。※再帰呼び出し（こちらを実行する）

    With ActiveSheet
    
        .Cells.ClearContents
        .Cells(1, "A") = "パス"
        .Cells(1, "B") = "ファイル名"
        .Cells(1, "C") = "ファイル容量（KB）"
        .Cells(1, "D") = "更新日時"
    
    End With
    
    Call Dir05("C:\TEST") 'フォルダーを指定する。

End Sub
'

'---------------------------------------------------------------------------------------------

Sub Dir05(FilePath As String)
    
    Dim Files As String
    Dim Folder As Object
    Dim countf As Long
    
    Files = Dir(FilePath & "\*.*")  '指定したフォルダー内の最初のファイルを取得します。
    
    With ActiveSheet
        countf = .Cells(Rows.Count, "B").End(xlUp).Row + 1  'B列の最終行＋１を取得する。
    
        .Cells(countf, "A") = FilePath  'A列にファイルパスを表示します。
        
        Do While Files <> ""  '現在のフォルダー内のファイルを全て読み込むまで繰り返します。
                     
                    .Cells(countf, "B") = Files  'ファイル名
                    .Cells(countf, "C") = FileLen(FilePath & "\" & Files)  'ファイルの容量
                    .Cells(countf, "D") = FileDateTime(FilePath & "\" & Files) 'ファイルの更新日時
                    countf = countf + 1 '転記先の行数を加算する＋１
                
            Files = Dir()  '次のファイルを読み込む
        Loop
    
        With CreateObject("Scripting.FileSystemObject")
            For Each Folder In .GetFolder(FilePath).SubFolders  'サブフォルダが無くなるまで繰り返す。
                Call Dir05(Folder.Path)  '次のフォルダーを指定して、再帰呼び出し（Dir05）同プログラムを実行
            Next Folder
        End With
        
    End With
    
End Sub
'
'