EXCEL VBA エクセルブックを開かないでデータを取得(ExecuteExcel4Macro)・別ブックからデータ取得・別ブックからのデータコピー

EXCEL VBA エクセルブックを開かないでデータを取得(ExecuteExcel4Macro)・別ブックからデータ取得・連続データ取得・別ブックからのデータコピー

'
'
Sub ExecuteExcel4Macro00() '指定したブック・セル位置より、ブックを開かずにデータを取得します。

    Range("A1") = ExecuteExcel4Macro("'C:\Users\akira\OneDrive\デスクトップ\[MasterBook.xlsx]sheet1'!R1C1")
    '別ブック（MasterBook.xlsx）より、ワークシート（Sheet01）のセル（A1）からデータを取得して取得元のブックのセル「A1」へ転記します。

End Sub
'

EXCEL VBA　ブックを開かずに指定したブックからデータを所得する。（別ブックからコピー）

'
'
Sub ExecuteExcel4Macro01()   'EXCEL VBA　ブックを開かずに指定したブックからデータを所得する。

    Dim L, I As Long

    For L = 1 To 10      '縦10行を繰り返します。
        For I = 1 To 7    '横７列を繰り返します。
            Cells(L, I) = ExecuteExcel4Macro("'C:\Users\akira\OneDrive\デスクトップ\[MasterBook01.xlsx]sheet1'!R" & L & "C" & I)
            '別ブックからセル単位でデータを順番に取得します。
        Next I
    Next L

End Sub
'

EXCEL VBA　ブックを開かずに指定したブックからデータを所得する。（別ブックからコピー）※データの取得範囲が分からない場合

'
'
Sub ExecuteExcel4Macro02()   '指定したブック・セル位置より、ブックを開かずにデータを取得します。


    Dim L, I As Long
    Dim Str As String

    L = 1
    I = 1
    
    Do
        Do
    
            Str = ExecuteExcel4Macro("'C:\Users\akira\OneDrive\デスクトップ\[MasterBook.xlsx]sheet1'!R" & L & "C" & I)
            '別ブックからセル単位でデータを順番に取得します。
            If Str <> "0" Then
                    Cells(L, I) = Str '習得したデータを同じワークシート・セル位置に転記します。
                    L = L + 1  '行セル＋１加算します。（縦）
                Else
                    L = 1      '1行に戻します。
                    I = I + 1  '列セル＋１加算します。（横）
            End If
        
        Loop While Str <> "0"
            Str = ExecuteExcel4Macro("'C:\Users\akira\OneDrive\デスクトップ\[MasterBook.xlsx]sheet1'!R" & L & "C" & I)
            '別ブックからセル単位でデータを順番に取得します。※次の列の1行目にデータが有るか確認します。
    Loop While Str <> "0"
            'データが無ければ、別ブックからデータ取得を終了します。
            
    MsgBox "別ブックからデータを取得しました。"

End Sub
'

EXCEL VBA　ブックを開かずに指定したブックからデータを所得する。（別ブックからコピー）※複数シートからデータを取得する。

'
'
'
Sub ExecuteExcel4Macro03()    '指定したブック・複数シートより、ブックを開かずにデータを取得します。

    Dim L, I, W, lRow As Long
    Dim Str, WsName As String
    Dim Ws01, Ws02 As Worksheet

    Set Ws02 = Worksheets("シート名一覧")

    lRow = Ws02.Cells(Rows.Count, "A").End(xlUp).Row 'ワークシート「シート一覧」A列の最終行を取得します。
    
    For W = 2 To lRow 'ワークシート「シート一覧」A列の最終行まで繰り返します。
        
        WsName = Ws02.Cells(W, "A")  'ワークシート名を順番に取得します。
        
        Set Ws01 = Worksheets(WsName)    'ワークシート名をセットします。Ws01へ
        
        L = 1: I = 1 'セル位置A1「Cells(1,1)」から取得できるように設定します。
        
        Do
            Do
        
                Str = ExecuteExcel4Macro("'C:\Users\akira\OneDrive\デスクトップ\[MasterBook.xlsx]" & WsName & "'!R" & L & "C" & I)
                '別ブックからセル単位でデータを順番に取得します。
                If Str <> "0" Then
                        Ws01.Cells(L, I) = Str  '取得したデータを同じワークシート・セル位置に転記します。
                        L = L + 1  '行セル＋１加算します。（縦）
                    Else
                        L = 1      '1行に戻します。
                        I = I + 1  '列セル＋１加算します。（横）
                End If
            
            Loop While Str <> "0"
                Str = ExecuteExcel4Macro("'C:\Users\akira\OneDrive\デスクトップ\[MasterBook.xlsx]" & WsName & "'!R" & L & "C" & I)
                '別ブックからセル単位でデータを順番に取得します。※次の列の1行目にデータが有るか確認します。
        Loop While Str <> "0"
                'データが無ければ、別ブックからデータ取得を終了します。
    
    Next W
    
    MsgBox "別ブックの指定したワークシート全てからデータを取得しました。"

End Sub
'

EXCEL VBA　ブックを開かずに選択したファイル（ブック）からデータを所得する。（別ブックからコピー）※毎回選択したフォルダーからファイルを取得

Sub ExecuteExcel4Macro04() 'ブックを開かずに選択したファイル（ブック）からデータを所得する。（ダイアログボックス表示）

    Dim ws01 As Worksheet
    Dim L, I As Long
    Dim Str As String
    Dim FilePath, FileName As Variant
           
    Set ws01 = Worksheets("顧客データ")
     
    FilePath = Application.GetOpenFilename(FileFilter:="Excelファイル,*.xls*") 'ファイルを選択するダイアログボックスを表示します。
    
    If FilePath = False Then  'ファイルが選択されているか判定します。
        Exit Sub  'ファイルが選択されていない場合は、プログラムから抜けます。
    End If
    
    ws01.Cells.ClearContents
            
    FileName = Dir(FilePath)  '選択したファイルパスからファイル名を抜き出します。
    FilePath = Replace(FilePath, FileName, "")  'ファイルパスからファイル名を削除します。
    
    L = 1: I = 1 'セル位置A1「Cells(1,1)」から取得できるように設定します。
    
    Do
        Str = ExecuteExcel4Macro("'" & FilePath & "[" & FileName & "]" & "顧客データM" & "'!R" & L & "C" & I)
        '選択した別ブックからセル単位でデータを順番に取得します。
        If Str <> "0" Then
            ws01.Cells(L, I) = Str
            L = L + 1 '行セル＋１加算します（縦）
        Else
            I = I + 1 '列セル＋１加算します（列）
            L = 1 '行を１行目に戻します。
             Str = ExecuteExcel4Macro("'" & FilePath & "[" & FileName & "]" & "顧客データM" & "'!R" & L & "C" & I)
             '選択した別ブックからセル単位でデータを順番に取得します。（次の列にデータが有るか確認します。）
        End If
    Loop While Str <> "0"  '取得するデータが無けれ終了します。
    
    MsgBox "選択したブックよりデータを取得しました。"
           
End Sub
'