EXCEL VBA　業務をスピードアップ！Excel VBAで請求書を自動作成する方法（新しいブックへの転記）

業務をスピードアップ！Excel VBAで請求書を自動作成する方法（新しいブックへの転記）

Excel VBAを活用した自動化のすすめ！請求書発行が楽になる！請求書データを別ブックに作成

'
'
Sub CreateInvoices()

    Dim wsList As Worksheet
    Dim wsInvoice As Worksheet
    Dim lastRow As Long
    Dim newWorkbook As Workbook
    Dim currentWorkbookPath As String
    Dim J, I As Long
    Dim userResponse As Integer

    ' 「請求書一覧」シートと「請求書」シートを設定します
    Set wsList = ThisWorkbook.Sheets("請求書一覧")
    Set wsInvoice = ThisWorkbook.Sheets("請求書")

    ' ユーザーによる確認を求めます
    userResponse = MsgBox("請求書を発行しますか？", vbYesNo + vbQuestion, "請求書発行確認")
    If userResponse = vbNo Then Exit Sub

    ' 「請求書一覧」シートの最終行を取得します
    lastRow = wsList.Cells(wsList.Rows.Count, "A").End(xlUp).Row

    ' 現在のブックのパスを取得します
    currentWorkbookPath = ThisWorkbook.Path

    ' 各行の請求書データを取得し、「請求書」シートに書き込み、新しいブックとして保存します
    For I = 2 To lastRow ' ヘッダ行をスキップするため2からスタートします
    
        If wsList.Cells(I, "O") = "" Then
                
            wsInvoice.Range("請求NO") = wsList.Cells(I, "A") '請求NO
            wsInvoice.Range("請求先") = wsList.Cells(I, "B")  '請求先
            wsInvoice.Range("件名") = wsList.Cells(I, "C")  '件名
            wsInvoice.Range("請求担当") = wsList.Cells(I, "D")  '請求担当
            
            wsInvoice.Range("項目①") = wsList.Cells(I, "E")  '項目①
            wsInvoice.Range("数量①") = wsList.Cells(I, "F")  '数量①
            wsInvoice.Range("単価①") = wsList.Cells(I, "G")  '単価①
            
            wsInvoice.Range("項目②") = wsList.Cells(I, "H")  '項目②
            wsInvoice.Range("数量②") = wsList.Cells(I, "I")  '数量②
            wsInvoice.Range("単価②") = wsList.Cells(I, "J")  '単価②
            
            wsInvoice.Range("項目③") = wsList.Cells(I, "K")  '項目③
            wsInvoice.Range("数量③") = wsList.Cells(I, "L")  '数量③
            wsInvoice.Range("単価③") = wsList.Cells(I, "M")  '単価③
            
            wsInvoice.Range("備考") = wsList.Cells(I, "N")  '備考
    
            ' 新しいブックを作成します
            Set newWorkbook = Workbooks.Add
    
            ' 「請求書」シートの内容を新しいブックにコピーします
            wsInvoice.Copy Before:=newWorkbook.Sheets(1)
    
            ' 余計なシートを削除します
            Application.DisplayAlerts = False
            For J = newWorkbook.Sheets.Count To 2 Step -1
                newWorkbook.Sheets(J).Delete
            Next J
            Application.DisplayAlerts = True
    
            ' 新しいブックを保存します
            newWorkbook.SaveAs Filename:=currentWorkbookPath & "\" & wsList.Range("A" & I) & "_" & wsList.Range("B" & I) & ".xlsx"
    
            ' 新しいブックを閉じます
            newWorkbook.Close SaveChanges:=False
            
            wsList.Cells(I, "O") = "済"  '請求書発行済み
              
        End If
        
    Next I

End Sub
'
'