EXCEL VBA 印刷のページ設定 PageSetup（印刷・余白・拡大縮小・ヘッダー・フッター・ページ番号・用紙サイズ）

EXCEL VBA 印刷のページ設定 PageSetup（印刷・余白・拡大縮小・ヘッダー・フッター・ページ番号・用紙サイズ）

VBAで印刷設定（ページ設定：ページタグ）

Sub PageSetup01()  'A4縦からA4横に用紙１ページに収めて印刷する。
    
    With Worksheets("Sheet1")
    
        .PageSetup.Orientation = xlLandscape '印刷の向きを「横」
        .PageSetup.PaperSize = xlPaperA4     '指定する用紙A4
        
        .PageSetup.FitToPagesWide = 1        '横１ページに指定
        .PageSetup.FitToPagesTall = 1        '縦１ページに指定
        
        .PageSetup.FirstPageNumber = 5      '先頭のページ番号を５に設定
        .PageSetup.CenterFooter = "-　" & "&P" & "　-"  'フッターにページ番号を表示
        
        .PrintPreview　　　 'プレビュー画面を表示させます。　　
    
    End With

End Sub

VBAで印刷設定（ページ設定：余白タグ）

Sub PageSetup02()  '指定する余白サイズに設定します。ページ中央の設定
    
    With Worksheets("Sheet1")
    
        .PageSetup.TopMargin = Application.CentimetersToPoints(3)  '上余白を3cmに設定
        .PageSetup.RightMargin = Application.CentimetersToPoints(4) '右余白を4cmに設定
        .PageSetup.LeftMargin = Application.CentimetersToPoints(5) '左余白を5cmに設定
        .PageSetup.BottomMargin = Application.CentimetersToPoints(6) '下余白を6cmに設定
        .PageSetup.HeaderMargin = Application.CentimetersToPoints(1.1) 'ヘッダー余白を1.1cmに設定
        .PageSetup.FooterMargin = Application.CentimetersToPoints(2.2)  'フッター余白を2.2cmに設定
        .PageSetup.CenterHorizontally = True  'ページ中央水平：ON
        .PageSetup.CenterVertically = False    'ページ中央垂直：OFF

        .PrintPreview    'プレビュー表示
  
    End With
    
End Sub

VBAで印刷設定（ページ設定：ヘッダー・フッター）

Sub PageSetup03() 'ヘッダー・フットーにタイトル名・ページ番号と日付・画像等を設定する。

    Dim This_Year As Date
    
    This_Year = Now()  '現在の日付を取得（年度表示用）

    With Worksheets("Sheet1")

        .PageSetup.Orientation = xlLandscape '印刷の向きを「横」
        
      '『ヘッダー』
        
        .PageSetup.LeftHeader = "&F" & vbCrLf & "&A" '左ヘッダー：ファイル名　＆　シート名
        .PageSetup.CenterHeader = "&""MS明朝""" & "&16 " & Format(This_Year, "yyyy年度") & "&16  支店別営業一覧表"
        .PageSetup.RightHeader = "&D" & vbCrLf & "&T" '右ヘッダー：現在の日付・時刻
        
      '『フッター』
        
        .PageSetup.LeftFooter = "&""MSゴシック"" &10&U経理課作成" '左フッター：MSゴシック・10サイズ・経理課作成”
        .PageSetup.CenterFooter = "&P / &N"  '中央フッター：ページ番号　/ 総ページ数
        
        .PageSetup.RightFooterPicture.Filename = ActiveWorkbook.Path & "\画像.jpg" '右フッター：画像を設定（ファイル設定）
        .PageSetup.RightFooter = "&G" '右フッター：画像を表示
        
        .PrintPreview    'プレビュー表示

    End With

End Sub

VBAで印刷設定（ページ設定：シートタグ）

Sub PageSetup04()  '印刷範囲を設定し、モノクロ印刷等を行います。

    
    Dim This_Mouth As Integer
    
    This_Mouth = Month(Now)    '現在の日付を取得（今月を取得）
    
    
    With Worksheets("Sheet3")
    
        .PageSetup.PaperSize = xlPaperA4   '指定する用紙
        .PageSetup.Orientation = xlLandscape '印刷の向きを「横」
        
        
        If This_Mouth >= 4 And This_Mouth <= 9 Then  '現在の月が４～９月は、上期を印刷範囲・それ以外は、下期
                .PageSetup.PrintArea = "A1:H14"  '上期を印刷範囲に設定
            Else
                .PageSetup.PrintArea = "J1:Q14"  '下期を印刷範囲に設定
        
        End If
            
        .PageSetup.PrintGridlines = True   '印刷枠線をONにする。
        
        .PageSetup.BlackAndWhite = True   '白黒印刷をONにする。
            
            
        
        .PrintPreview    'プレビュー表示
    
    End With

End Sub