EXCEL VBA PDFファイルデータをEXCELシートに読み込む（文字列データ・表データ・自動収集・テクニック）

EXCEL VBA PDFファイルデータをEXCELシートに読み込む（文字列データ・表データ・自動収集・テクニック）

EXCEL VBA PDFファイルデータをEXCELシートに読み込む（PDF文字列データ）

'
'
Sub PDF_WORD_EXCEL01() 'FDFデータをWordで開きEXCELへ転記します。

    Dim WordDoc
    Dim WordApp As Object
    Dim I As Long
    
    Set WordApp = CreateObject("Word.Application")
    
    WordApp.Visible = True 'Wordアプリケーションを起動します。
    
    Set WordDoc = WordApp.Documents.Open("C:\Users\akira\OneDrive\デスクトップ\サンプル１.pdf")
    '指定したPDFファイルをWordで開きます。
    For I = 1 To WordDoc.Paragraphs.Count  'Word（PDF）の文字列の最終行まで繰り返す。
    
        With ActiveSheet  'EXCELアクティブシートにWordの文字列をA列に一行ずつ転記します。
            .Cells(I, 1).Value = WordDoc.Range.Paragraphs(I).Range.Text
        End With
    
    Next I

    WordApp.Quit 'Wordアプリケーションを閉じる
    
    
End Sub
'

EXCEL VBA PDFファイルデータをEXCELシートに読み込む（PDF全でのデータ・表・文字列含む）

Aパターン【※VBE Word Object Library 参照設定無し】

'
'
Sub PDF_Word_EXCEL02() 'PDFデータをEXCELシートに貼り付ける（Word）

    
    Dim WordDoc
    Dim WordApp As Object
    Set WordApp = CreateObject("Word.Application")
        
    
    WordApp.Visible = True   'Wordアプリケーションを起動します。
    
    Set WordDoc = WordApp.Documents.Open("C:\Users\akira\OneDrive\デスクトップ\サンプル２.pdf")
    '指定したPDFファイルをWordで開きます。
        
    With WordApp 'PDFで開いたWordデータを全選択コピーします。
        .Selection.WholeStory
        .Selection.Copy
    End With

    With ActiveSheet  'EXCELの選択シート（アクティブ）に対して貼り付けます。
        .Range("A1").Select  '貼り付け元をセル「A1」に指定する。
        .Paste
    End With
    
    WordApp.Quit  ''Wordアプリケーションを閉じる

End Sub
'

Bパターン【※VBE Word Object Library 参照設定必須】

'
'
Sub PDF_Word_EXCEL03()  '参照設定必要　'PDFデータをEXCELシートに貼り付ける
    
    Dim WordDoc As Document
    Dim WordApp As Object
    Set WordApp = CreateObject("Word.Application")
    
    WordApp.Visible = True   'Wordアプリケーションを起動します。
    
    Set WordDoc = WordApp.Documents.Open("C:\Users\akira\OneDrive\デスクトップ\サンプル２.pdf.pdf")
    '指定したPDFファイルをWordで開きます。
        
    With WordDoc 'PDFで開いたWordデータを全選択コピーします。
        .StoryRanges(wdMainTextStory).Copy
    End With
    
    With ActiveSheet  'EXCELの選択シート（アクティブ）に対して貼り付けます。
        .Range("A1").Select  ' '貼り付け元をセル「A1」に指定する。
        .Paste
    End With
    
    WordApp.Quit  ''Wordアプリケーションを閉じる

End Sub
'

EXCEL VBA PDFファイルデータをEXCELシートに読み込む（数字は、数値データとして取り扱う・EXCELで2次加工可能）

'
'
Sub PDF_WORD_EXCEL04() '読み込むPDFファイルをテキストデータは、文字列として、数値は、数値データとして2次利用出来るように貼り付ける。

    Dim WordDoc
    Dim WordApp As Object
    Dim I, L, T, lRow, lCol As Long
    Dim TableData As String
    
    Set WordApp = CreateObject("Word.Application")
    
    WordApp.Visible = True 'Wordアプリケーションを起動します。
    
    Set WordDoc = WordApp.Documents.Open("C:\Users\akira\OneDrive\デスクトップ\サンプル３.pdf")
    '指定したPDFファイルをWordで開きます。
    
    T = 1　’表の初期値（1行目）
    
    ActiveSheet.Cells.Clear 'アクティブシートをクリアします。
    
    With WordDoc.tables(1)
    
    lRow = .Rows.Count  '表の最終行を代入
    lCol = .Columns.Count + 1  '表の最終列＋１を代入
 
        For L = 1 To .Rows.Count  '表の最終行まで繰り返す。
            For I = 1 To .Columns.Count + 1  '表の最終列＋１まで繰り返す。
                TableData = Replace(WordDoc.Range.Paragraphs(T).Range.Text, Chr(7), "")
                  '取り込んだテキストの末尾に「・」（改行）付いてくるのでChr(7)で削除します。
                  
                  If IsNumeric(TableData) = True Then  '数値データならば（文字列⇒数値）へ変換
                         TableData = CLng(TableData) '数値データに変換する
                  End If
                
                  ActiveSheet.Cells(L, I).Value = TableData  'EXCELシートのセルごとに表データを転記します。
                
            T = T + 1  '表の次のデータに移す（位置を加算）
    
            Next I
        Next L
    End With
    
    With ActiveSheet '表を作成します。
        .Range(Cells(1, 2), Cells(1, lCol)).Interior.ColorIndex = 34  '先頭行の見出し（背景色：水色）
        .Range(Cells(1, 2), Cells(lRow + 1, 2)).Interior.ColorIndex = 35  '列（支店）見出し（背景色：薄緑）
        .Range(Cells(1, 2), Cells(lRow + 1, lCol)).Borders.LineStyle = xlContinuous
        .Cells(lRow + 1, 2) = "合計"
    End With
    
    
    With Range("C" & lRow + 1) '合計の作成
        .Formula = "=SUM(C2:C" & lRow & ")"   'C列の最終行にSUM関数「C2～最終行」を代入
        .AutoFill Destination:=.Resize(1, lCol - 2)  'AutoFillを使い横４列分複写する
    End With
    
    WordApp.Quit 'Wordアプリケーションを閉じる
    
End Sub
'