Excel VBA　選択した位置のファイルとフォルダのツリー構造を見やすく表示する方法・ファイル管理を効率化

Excel VBAでディレクトリ構造を一目で把握！初心者でもできるフォルダツリー表示の作り方(自動化・業務効率化）

Excel VBAでフォルダ構造を簡単に可視化！フォルダ内のすべてを見せる – Excelでツリー表示の作成・ファイル管理の効率化テクニック①

'
' 外部宣言 - 厳格な変数宣言を強制
Option Explicit

' ShowFolderTreeサブルーチンの定義開始
Sub ShowFolderTree()
    ' 変数の宣言
    Dim fs As Object, folder As Object, subfolder As Object
    Dim path As String, row As Integer

    ' ファイルダイアログを使用してユーザーにフォルダを選択させる
    With Application.FileDialog(msoFileDialogFolderPicker)
        .Title = "フォルダを選択してください" ' ダイアログのタイトル設定
        .AllowMultiSelect = False ' 複数選択を不可に設定
        If .Show <> -1 Then Exit Sub ' ダイアログがキャンセルされた場合、サブルーチンを終了
        path = .SelectedItems(1) ' 選択されたフォルダのパスを取得
    End With

    ' ファイルシステムオブジェクトを作成し、選択されたフォルダを取得
    Set fs = CreateObject("Scripting.FileSystemObject")
    Set folder = fs.GetFolder(path)

    row = 1 ' シートの開始行を設定

    ' ListFoldersを呼び出し、フォルダとファイルのツリーを表示
    ListFolders folder, row, ""

    ' 列幅を自動調整
    Columns("A:A").AutoFit
End Sub

' ListFoldersプライベートサブルーチンの定義開始
Private Sub ListFolders(ByVal folder As Object, ByRef row As Integer, ByVal indent As String)
    Dim subfolder As Object, file As Object ' 変数宣言
    Dim ws As Worksheet ' ワークシート変数の宣言

    Set ws = ThisWorkbook.Sheets(1) ' ワークシート1を設定

    ' フォルダ名をインデント付きで表示
    ws.Cells(row, 1).Value = indent & "【" & folder.Name & "】"
    row = row + 1 ' 行番号を＋１加算

    ' サブフォルダを再帰的に処理
    For Each subfolder In folder.SubFolders
        ListFolders subfolder, row, indent & "    " ' インデントを追加して呼び出し
    Next subfolder

    ' フォルダ内の全ファイルを表示
    For Each file In folder.Files
        ws.Cells(row, 1).Value = indent & "    ＊" & file.Name
        row = row + 1 ' 行番号を＋１加算
    Next file
End Sub
'
'

Excel VBAでファイルエクスプローラーを作成しよう！フォルダツリーの自動表示法・フォルダーとファイルを簡単にリストアップ

’
’
Option Explicit

' メインプロシージャ
Sub ShowFolderTree02()
    ' オブジェクト変数の宣言
    Dim fs As Object, folder As Object, subfolder As Object
    Dim path As String, row As Integer, LastLow As Long

    ' ユーザーにフォルダを選択させる
    With Application.FileDialog(msoFileDialogFolderPicker)
        .Title = "フォルダを選択してください"  ' ダイアログのタイトル設定
        .AllowMultiSelect = False            ' 複数選択不可
        If .Show <> -1 Then Exit Sub         ' ダイアログを表示し、選択がなければ終了
        path = .SelectedItems(1)             ' 選択されたフォルダのパスを取得
    End With

    ' FileSystemObjectの作成とフォルダオブジェクトの取得
    Set fs = CreateObject("Scripting.FileSystemObject")
    Set folder = fs.GetFolder(path)

    ' Excelの操作開始
    row = 2  ' 開始行
    LastLow = Cells(Rows.Count, "A").End(xlUp).Row  ' 既存データの最終行を取得
    Range("A2:D" & LastLow + 1).ClearContents       ' 既存データをクリア

    ' フォルダとファイルのツリーをリストアップ
    ListFolders folder, row, ""

    ' 列幅の自動調整
    Columns("A:D").AutoFit
End Sub

' フォルダとファイルをリストアップする再帰的サブプロシージャ
Private Sub ListFolders(ByVal folder As Object, ByRef row As Integer, ByVal indent As String)
    Dim ws As Worksheet
    Set ws = ThisWorkbook.Sheets(1)  ' ワークシートの設定

    ' フォルダ名と詳細をシートに表示
    ws.Cells(row, 1).Value = indent & "【" & folder.Name & "】"
    ws.Cells(row, 2).Value = folder.DateLastModified
    ws.Cells(row, 3).Value = "フォルダー"
    row = row + 1

    ' サブフォルダを再帰的に処理
    Dim subfolder As Object
    For Each subfolder In folder.SubFolders
        ListFolders subfolder, row, indent & "    "
    Next subfolder

    ' 各ファイルをリストアップ
    Dim file As Object
    For Each file In folder.Files
        ws.Cells(row, 1).Value = indent & "    ＊" & file.Name
        ws.Cells(row, 2).Value = file.DateLastModified
        ws.Cells(row, 3).Value = "ファイル"
        ws.Cells(row, 4).Value = file.Size / 1024  ' ファイルサイズをKBで表示
        row = row + 1
    Next file
End Sub
’
’