EXCEL VBA ユーザー設定リストに登録（追加）・削除 『オリジナルリストの作成・順序　AutoFill』

EXCEL VBA ユーザー設定リストに登録（追加）・削除 『新しいリスト・オリジナルリストの作成・順序　AutoFill』

登録する配列を指定してユーザー設定リストに登録：Application.AddCustomList(配列)

Sub UserList01()

    Dim Userlist As Variant
    Dim ListNo As Long
    
    Userlist = Array("アメリカ", "中国", "日本", "ドイツ", "イギリス", "フランス", "インド", "イタリア", "ブラジル", "カナダ")
    
    Application.AddCustomList Userlist   '上記の配列内容を'「ユーザー設定リスト」に新規登録する。（UserList）
    
    ListNo = Application.GetCustomListNum(Userlist)  '「ユーザー設定リスト」に登録した登録番号を取得
    
    MsgBox "ユーザー設定リストに新規登録した番号は、" & ListNo & "です。"

End Sub

ユーザー設定リストに登録したリストをAutoFill機能でセルに出力

Sub UserList02()

    Dim Userlist As Variant
    Dim ListNo, ArrayCount As Long
    
    Userlist = Array("東京本店", "神奈川支店", "埼玉支店", "千葉支店", "茨木支店", "栃木支店")
    
    Application.AddCustomList Userlist  '上記の配列内容を'「ユーザー設定リスト」に新規登録する。（UserList）
    
    ListNo = Application.GetCustomListNum(Userlist) '「ユーザー設定リスト」に登録した登録番号を取得
    
    ArrayCount = UBound(Userlist) '配列で登録した件数を把握する。※６個
    
    
    Range("A2") = "東京本店" 'AutoFill用の一件目を登録
    Range("A2").AutoFill Range("A2:A" & ArrayCount + 2)  'AutoFill機能を使いA列に支店名を表示する（ユーザー設定リストに登録した分）
    
    Application.DeleteCustomList (ListNo)  '登録した「ユーザー設定リスト」を削除
    
End Sub

指定したセルデータからユーザー設定リストに登録

Sub UserList03()

    Dim Userlist  As Variant
    Dim ListNo, lRow As Long

    
    lRow = Cells(Rows.Count, "I").End(xlUp).Row  'I列「勘定科目」の最終行を取得
    
    Userlist = Range("I4:I" & lRow)  'I列の勘定科目を配列に登録
    
    Application.AddCustomList Userlist  '「ユーザー設定リスト」に新規登録する。I列の「勘定科目」

    ListNo = Application.GetCustomListNum(Userlist)  '「ユーザー設定リスト」に登録した登録番号を取得
    
    Range("A4") = "旅費交通費"  'AutoFill用の一件目を登録
    Range("A4").AutoFill Range("A4:A10")  'AutoFill機能を使いA列に「ユーザー設定リスト」に登録した「勘定科目」を表示
    
    Range("B3") = "4月"  'AutoFill用の一件目を登録
    Range("B3").AutoFill Range("B3:G3")  'AutoFill機能を使い3行目に４月～９月を表示

    Application.DeleteCustomList (ListNo)  '登録した「ユーザー設定リスト」を削除

End Sub